1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
|
package Bot::Zulip::Chess;
use 5.020;
use feature 'signatures', 'postderef';
use experimental 'signatures', 'postderef';
use Moose;
no warnings 'experimental::signatures';
no warnings 'experimental::postderef';
use Chess::Rep;
use Try::Tiny;
use WebService::Zulip;
has api_key => (
is => 'ro',
isa => 'Str',
required => 1,
);
has api_user => (
is => 'ro',
isa => 'Str',
required => 1,
);
has bot_name => (
is => 'ro',
isa => 'Str',
required => 1,
);
has white_player => (
is => 'rw',
isa => 'Str',
predicate => 'has_white_player',
clearer => 'clear_white_player',
);
has black_player => (
is => 'rw',
isa => 'Str',
predicate => 'has_black_player',
clearer => 'clear_black_player',
);
has turn => (
is => 'rw',
isa => 'Str',
default => 'white',
);
has _zulip => (
is => 'ro',
isa => 'WebService::Zulip',
lazy => 1,
default => sub ($self) {
WebService::Zulip->new(
api_key => $self->api_key,
api_user => $self->api_user,
)
},
);
has _queue => (
is => 'ro',
isa => 'HashRef',
lazy => 1,
default => sub ($self) {
$self->_zulip->get_message_queue
},
);
has _chessboard => (
is => 'ro',
isa => 'Chess::Rep',
lazy => 1,
default => sub { Chess::Rep->new },
clearer => '_clear_chessboard',
);
sub run ($self) {
while (1) {
$self->step
}
}
sub step ($self) {
my $res = $self->_zulip->get_new_events(
queue_id => $self->_queue->{queue_id},
last_event_id => $self->_queue->{last_event_id},
dont_block => 'false',
);
for my $event ($res->{events}->@*) {
next unless $event->{type} eq 'message';
my $message = $event->{message};
next if $message->{type} eq 'private';
my $bot_name = $self->bot_name;
my $content = $message->{content};
next unless $content =~ s/^\@\*\*$bot_name\*\*//;
$content =~ s/^\s*|\s*$//g;
my $response = $self->handle_move(
$message->{sender_full_name}, $content
);
$self->_zulip->send_message(
content => $response,
subject => $message->{subject},
to => $message->{sender_email},
type => $message->{type},
);
}
$self->_queue->{last_event_id} = $self->_zulip->get_last_event_id($res);
}
sub handle_move ($self, $player, $move) {
if (!$self->players_turn($player)) {
return "It's not your turn!";
}
else {
if ($self->needs_new_player) {
$self->set_new_player($player);
}
return try {
$self->_chessboard->go_move($move);
my $state = $self->draw_state;
$self->increment_turn;
$state
}
catch {
s/ at .* line .*//r;
};
}
}
sub needs_new_player ($self) {
return !$self->has_white_player || !$self->has_black_player
}
sub set_new_player ($self, $player) {
if (!$self->has_white_player) {
$self->white_player($player)
}
elsif (!$self->has_black_player) {
$self->black_player($player);
}
else {
die "Both players are already full";
}
}
sub increment_turn ($self) {
$self->turn($self->turn eq 'white' ? 'black' : 'white');
}
sub draw_state ($self) {
my $board = $self->format_board =~ s/^/ /gmr;
my $status = $self->_chessboard->status;
if ($status->{mate}) {
$board .= "\nCHECKMATE\n";
$self->reset_board;
}
elsif ($status->{stalemate}) {
$board .= "\nSTALEMATE\n";
$self->reset_board;
}
elsif ($status->{check}) {
$board .= "\nCHECK\n";
}
return $board;
}
sub players_turn ($self, $player) {
my $method = $self->turn . '_player';
my $expected_player = $self->$method;
return if grep { $_ eq $player } grep { defined } (
$self->white_player, $self->black_player
);
return 1 if !defined($expected_player);
return 1 if $expected_player eq $player;
return;
}
sub reset_board ($self) {
$self->turn('white');
$self->clear_white_player;
$self->clear_black_player;
$self->_clear_chessboard;
}
my %pieces = (
p => "\N{BLACK CHESS PAWN}",
P => "\N{WHITE CHESS PAWN}",
n => "\N{BLACK CHESS KNIGHT}",
N => "\N{WHITE CHESS KNIGHT}",
b => "\N{BLACK CHESS BISHOP}",
B => "\N{WHITE CHESS BISHOP}",
r => "\N{BLACK CHESS ROOK}",
R => "\N{WHITE CHESS ROOK}",
q => "\N{BLACK CHESS QUEEN}",
Q => "\N{WHITE CHESS QUEEN}",
k => "\N{BLACK CHESS KING}",
K => "\N{WHITE CHESS KING}",
);
sub format_board ($self) {
my $board = $self->_chessboard->dump_pos;
for my $piece (keys %pieces) {
$board =~ s/$piece/$pieces{$piece}/g;
}
$board =~ s/\+/\N{BOX DRAWINGS LIGHT VERTICAL AND HORIZONTAL}/g;
$board =~ s/\|-/\N{BOX DRAWINGS LIGHT VERTICAL AND RIGHT}-/g;
$board =~ s/-\|/-\N{BOX DRAWINGS LIGHT VERTICAL AND LEFT}/g;
$board =~ s/\|/\N{BOX DRAWINGS LIGHT VERTICAL}/g;
$board =~ s/-/\N{BOX DRAWINGS LIGHT HORIZONTAL}/g;
$board = "\N{BOX DRAWINGS LIGHT DOWN AND RIGHT}"
. ("\N{BOX DRAWINGS LIGHT HORIZONTAL}\N{BOX DRAWINGS LIGHT DOWN AND HORIZONTAL}" x 7) . "\N{BOX DRAWINGS LIGHT HORIZONTAL}"
. "\N{BOX DRAWINGS LIGHT DOWN AND LEFT}"
. "\n" . $board . "\n"
. "\N{BOX DRAWINGS LIGHT UP AND RIGHT}"
. ("\N{BOX DRAWINGS LIGHT HORIZONTAL}\N{BOX DRAWINGS LIGHT UP AND HORIZONTAL}" x 7) . "\N{BOX DRAWINGS LIGHT HORIZONTAL}"
. "\N{BOX DRAWINGS LIGHT UP AND LEFT}"
. "\n A B C D E F G H\n";
my @board = split "\n", $board;
my $n = 1;
for my $i (0..$#board) {
my $prefix = $i % 2 == 1 && $i < 16 ? $n++ : " ";
$board[$i] = $prefix . $board[$i];
}
join("\n", @board)
}
__PACKAGE__->meta->make_immutable;
no Moose;
1;
|
