Adding new entry vaults by ShioriC.

git-svn-id: https://crawl-ref.svn.sourceforge.net/svnroot/crawl-ref/trunk@6831 c06c8d41-db1a-0410-9941-cceddc491573

1 files changed, 265 insertions, 0 deletions

diff --git a/crawl-ref/source/dat/entry.des b/crawl-ref/source/dat/entry.des
index 66306c8a88..712ff5bf21 100644
--- a/crawl-ref/source/dat/entry.des
+++ b/crawl-ref/source/dat/entry.des
@@ -4,6 +4,271 @@
 
 
 ##############################################################################
+# Shiori's entry vaults
+##############################################################################
+
+########################################
+# Entry with hidden altar
+NAME:    shiori_entry_001
+TAGS:    entry no_monster_gen no_secret_doors no_pool_fixup
+ORIENT:  float
+SUBST:   B:.A , A:.x
+NSUBST:  E= 1=+ / *=+=x
+SUBST:   +:@+ , d=mlwG
+SHUFFLE: ef/gh/ij
+SUBST:   g=> , h=C/x , e=x , f=w , i=x , j=l
+MAP
+xxxExxxxxxx
+xAB.BAxfffx
+xB...Bxxehx
+E..{..=dghx
+xB...Bxxihx
+xAB.BAxjjjx
+xxxExxxxxxx
+ENDMAP
+
+#########################################
+# A horror show for the beginning adventurer (Shiori)
+NAME:    whats_in_store_for_you
+TAGS:    entry no_monster_gen no_pool_fixup no_item_gen
+ORIENT:  west
+SHUFFLE: =@/AB ,  AB/CD
+SUBST:   A== , B=@ , C=x , D=x
+NSUBST:  T = 1=T... / *=.
+KFEAT:   T = net trap
+# Seemingly pointless, since there are no active foes here... but
+# it had an unnerving effect on me the one time it happened by chance
+# ("Ack! Now I'm trapped too! Help!") so I coded it in. ^.^
+SHUFFLE: M/N/O/P/Q
+SUBST:   P= MNO
+: if crawl.one_chance_in(2) then
+KFEAT: M=shallow_water
+KFEAT: N=shallow_water
+KFEAT: O=shallow_water
+KFEAT: Q=shallow_water
+: else
+KFEAT: M=floor
+KFEAT: N=floor
+KFEAT: O=floor
+KFEAT: Q=floor
+: end
+
+KMONS: M= human / elf / orc
+#KMONS: M= human / elf / orc, nothing / naga, nothing / centaur, nothing / draconian, nothing / ogre, nothing / minotaur / troll / kobold, mummy / ghoul / w:30 nothing
+# no vampires or ogre-mages because they can get out of their cells or
+# create threats outside
+# no merfolk, alive or undead, because they insist on having deep water
+# in their cells, which annoys me
+# other player species don't exist as monsters
+KMONS: N= human zombie / elf zombie / orc zombie / naga zombie / centaur zombie / draconian zombie / ogre zombie / minotaur zombie / troll zombie / kobold zombie / mummy / w:50 nothing
+# ghouls drop out because they need sustenance and can't be reanimated
+# once starved
+KMONS: O= human skeleton / elf skeleton / orc skeleton / naga skeleton / centaur skeleton / draconian skeleton / ogre skeleton / minotaur skeleton / troll skeleton / kobold skeleton / mummy / w:80 nothing
+# and now for something completely different
+# if any of these turn out to be able to escape or project spells out of
+# their cells, they should be removed (I wanted to have killer klowns...)
+KMONS: Q= orb of fire / ice dragon / shadow dragon / iron dragon / w:1 golden dragon / large abomination / tentacled monstrosity / w:1 black draconian; nothing / w:1 mottled draconian; nothing / w:1 yellow draconian; nothing / w:2 green draconian; nothing / w:1 purple draconian; nothing / w:2 red draconian; nothing / w:1 white draconian; nothing / w:1 pale draconian; nothing / nothing
+# And if anyone is careless with a wand of digging after coming through
+# all this to begin with, on their own head be it
+MAP
+xxxxxxxxxxxxxx     xxxxxxxxx
+xxxxxxxxMxMxMxxxxxxxMxMxMxMx
+xxxxxxxxmxmxmxMxMxMxmxmxmxmxxxx@x
+xxxxxx[......xmxmxmx.....T.mMxx=xx
+xxxxxx{..............xmxmxTxmx...xxx
+xxxxxx(..........xmxmxMxMm.T.T.>.mMx
+xxxxxxxxmxmxmxmxmxMxMxxxxxmxmx...xxx
+xxxxxxxxMxMxMxMxMxxxxx   xMxMxxAxx
+xxxxxxxxxxxxxxxxxx       xxxxxxBx
+ENDMAP
+
+###################################################
+# A simple little maze-like thing
+NAME:    shiori_entry_002
+ORIENT:  float
+TAGS:    entry no_monster_gen no_secret_doors
+SHUFFLE: [{(
+SUBST:   1= . 1:2 2:1 3:1
+NSUBST:  A= 1= + / 1= = / 2= =x / *= x
+NSUBST:  B= 1= + / 1= = / 2= =x / *= x
+NSUBST:  C= 1= + / 1= = / *= =x
+NSUBST:  @= 5=@+ / *= =x
+MONS:    fungus, plant, butterfly
+MAP
+xxx@xxx@xxx@xxx
+x.111.B0B.111.x
+xCx1xAxxxAx1xCx
+@.x.A11111A.x.@
+x1x.x1[1(1x.x1x
+x1xBx11>11xBx1x
+x1x.x11{11x.x1x
+@.x.A11111A.x.@
+xCx1xAxxxAx1xCx
+x.111.B0B.111.x
+xxx@xxx@xxx@xxx
+ENDMAP
+
+#########################################
+# good luck! (Shiori)
+NAME:    shiawase
+TAGS:    entry no_monster_gen no_rotate no_vmirror
+CHANCE:  5
+ORIENT:  float
+ITEM:    bread ration, meat ration, apple, orange, banana, choko, pear
+SUBST:   . = .:100 $ % d
+SHUFFLE: +=
+SUBST:   =:==x , x:xvcb
+MAP
+      x+x
+      x.x
+    xxx.xxx
+    =..{..=
+xxxxxxx.xxxxxxx
++.............+
+xxxx.xxxxx.xxxx
+  xx.xxxxx.xx
+  +.........+
+ xxxxxx.xxxxxx
+ =.....[.....=
+ xxxxxx.xxxxxx
+      x.x
+      x.x
+      x+x
+ENDMAP
+
+
+##############################################
+# Angband town! but this isn't Angband, so all
+# the shops are empty. Well, mostly... (Shiori)
+NAME:    angband_town
+ORIENT:  float
+TAGS:    entry no_rotate
+NSUBST:  { = { / > / .
+NSUBST:  = = 3== / *=x
+SHUFFLE: ABC/DEF/GHI/JKL/MNO/PQR/STU
+NSUBST:  A = 1:=/x, B = *=%$, C = [/x
+NSUBST:  D = 1:=/x, E = *=%$, F = (/x
+SUBST:   G=x, H=x, I=x, J=x, K=x,L=x, M=x, N=x, O=x, P=x, Q=x, R=x
+SUBST:   S=x, T=x, U=x
+SUBST:   x=xxxcc
+MAP
+xxxx=xxxxxxxxxxxxxx=xxxxxxxxxxxxxx=xxxxx
+x......................................x
+x.xAxxx..xxxxx....xSSSx....xPxxx.xxxMx.x
+=.ABCxx..xxxx+..{.STUTS..{.PQRxx.+xONM.=
+x.xCxxx...........xTxxx....xPxx+.xxxMx.x
+x.xxxxx..{........xxx+x................x
+x.xx+xx......{.............{.....xxxDx.x
+x.........xxxx+xx..xx+x...xxJxx..+xFED.x
+=.xxxx+...GHIxxxx..xxxx...xxKLx{.xxxFx.=
+x.xxxxx.{.xGxxxxx..xxxx.{.+xJxx..xxxxx.x
+x......................................x
+xxxx=xxxxxxxxxxxxxx=xxxxxxxxxxxxxxx=xxxx
+ENDMAP
+
+###################################
+# Four element entry (Shiori)
+# Pretty hazardous, but the Earth side is always safe to leave through.
+# Players can safely watch at the clouds. Autoexplore will not run into
+# the chambers, players have to search for the secret door. Likewise,
+# all exits are secret except for the safe one.
+# We may delegate this vault to another branch, where we need to take
+# less caution measures.
+NAME:   elemental_entry
+TAGS:   entry no_monster_gen
+ORIENT: float
+MARKER: A = lua:fog_machine { \
+            pow_max = 20, delay_min = 50, delay_max = 300, \
+            size = 12, start_clouds = 1, \
+            cloud_type = "noxious fumes" }
+SUBST:  A=a ,  a=aaam
+COLOUR: a=lightgreen
+SUBST:  a=.
+MARKER: W = lua:fog_machine{\
+            pow_max = 20, delay_min = 50, delay_max = 300, \
+            size = 12, start_clouds = 1, \
+            cloud_type = "freezing vapour"}
+SUBST:  W=w
+MARKER: F= lua:fog_machine {\
+            pow_max = 20, delay_min = 50, delay_max = 300, \
+            size = 12, start_clouds = 1, \
+            cloud_type = "flame"}
+SUBST:  F=f
+COLOUR: f=red
+SUBST:  f=lll.
+MARKER: E= lua:fog_machine{\
+            pow_max = 20, delay_min = 50, delay_max = 300, \
+            size = 12, start_clouds = 1, \
+            cloud_type = "black smoke"}
+SUBST:  E=e , e=cxbveeee
+COLOUR: e= brown
+SUBST:  e=.
+MONS:   butterfly
+SHUFFLE: XZ
+NSUBST:  Z= ) / ]
+NSUBST: X= ( / [
+MAP
+      ccc===ccc
+     cc..aaa..cc
+     c.aaaAaaa.c
+     c..aaaaa..c
+     cc...a...cc
+ ccccccccn=ncccccccc
+cc..ccccc1.1ccccc..cc
+c.w..ccccc+ccccc..f.c
+c.ww.cccX...Zccc.ff.c
+=www.nwc.....cln.fff=
+=wWww=.+..{..+.=ffFf=
+=www.nwc.....cln.fff=
+c.ww.cccZ...Xccc.ff.c
+c.w..ccccc+ccccc..f.c
+cc..cccccG.Gccccc..cc
+ ccccccccn=ncccccccc
+     cc...e...cc
+     c..eeeee..c
+     c.eeeEeee.c
+     cc..eee..cc
+      ccc+++ccc
+ENDMAP
+
+#####################################
+# I am the great and powerful Oz! Pay no attention to the man behind
+# the curtain! (Shiori)
+# ...if you stick close to the wall, you should always be able to
+# avoid the flame clouds.
+NAME:   oz_shiori
+CHANCE: 10000
+TAGS:   entry
+ORIENT: float
+NSUBST: 1 = 1/%
+MONS:   kobold/goblin/hobgoblin
+MARKER: # = lua:fog_machine { \
+            pow_max = 5, delay_min = 100, delay_max = 150, \
+            size = 5, start_clouds = 1, \
+            cloud_type = "flame" }
+KFEAT:  # = l
+COLOUR: ' = red
+SUBST:  ' = .
+MAP
+bbbbbbbbb
+b.(.{.[.b
+b.b...b.b
+b.......b
+b.......b
+b.b'''b.b
+b.'''''.b
+@.'#'#'.@
+b.b'G'b.b
+b.......b
+bbb+b+bbb
+=1=.b.=1=
+bbb.b.bbb
+  b@b@b
+ENDMAP
+
+
+
+##############################################################################
 # Matthew's entry vaults
 ##############################################################################