1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
|
%{
// levcomp.lpp:
// Level compiler lexer for Dungeon Crawl Stone Soup.
//
// Based loosely on NetHack's lev_comp.l
#include "AppHdr.h"
#include "mapdef.h"
#include "levcomp.tab.h"
#include <cstring>
#include <queue>
static bool alloced = false;
std::queue<const char *> free_queue;
static void flush_free_queue(unsigned int max_allowed)
{
while (free_queue.size() > max_allowed)
{
const char *s = free_queue.front();
free((void *) s);
free_queue.pop();
}
}
static void add_to_queue(const char *s)
{
free_queue.push(s);
flush_free_queue(100);
}
static void clean()
{
if (yylval.text && alloced)
add_to_queue(yylval.text);
yylval.text = NULL;
alloced = false;
}
static char *copy_text(bool trim_right, int strip_trailing)
{
char *newstring = NULL;
if ((yylval.text = newstring = strdup(yytext)))
{
alloced = true;
char *s = NULL;
if (trim_right)
{
s = newstring + strlen(newstring) - 1;
while (isspace(*s) && s >= newstring)
*s-- = 0;
}
if (strip_trailing)
{
if (!s)
s = newstring + strlen(newstring) - 1;
while (s >= newstring && --strip_trailing >= 0)
*s-- = 0;
}
}
return (newstring);
}
static void settext(bool trim_right = false, int strip_trailing = 0)
{
clean();
char *newstring = copy_text(trim_right, strip_trailing);
yylval.text = newstring;
}
%}
%x MAPDEF
%x LUA
%x LUA_ONELINER
%s ARGUMENT
%s MNAME
%s KEYWORDS
%x ITEM_LIST
%x TOEOL
%option yylineno
%option never-interactive
NSPACE [^\ \t\r\n]
%%
<MAPDEF>^\s*ENDMAP[ ]* { BEGIN(INITIAL); }
<MAPDEF>^[^\r\n\t]+ {
settext(true);
return MAP_LINE;
}
<MAPDEF>^[ ]*\r?\n return CHARACTER;
<MAPDEF># return CHARACTER;
<MAPDEF>[\ ][^\ \r\n] return CHARACTER;
<MAPDEF>[ ]*\r?\n ;
<LUA>\s*\}\}[ \t]*$ { BEGIN(INITIAL); }
<LUA>[^\r\n]+\}\}[ \t]*$ {
settext(true, 2);
BEGIN(INITIAL);
return LUA_LINE;
}
<LUA>[^\r\n]+ {
settext();
return LUA_LINE;
}
<LUA>\r?\n ;
<LUA_ONELINER>[^\r\n]+$ {
settext();
return LUA_LINE;
}
<LUA_ONELINER>\r?\n { BEGIN(INITIAL); }
<KEYWORDS>[A-Za-z_0-9\-]+ {
settext();
return STRING;
}
<KEYWORDS>[ \t]+ ;
<KEYWORDS>[ \t]*\r?\n { BEGIN(INITIAL); }
<ITEM_LIST>[^, \t\r\n][^,\r\n]*[^, \t\r\n] {
settext();
return ITEM_INFO;
}
<ITEM_LIST>[^, \t\r\n] {
settext();
return ITEM_INFO;
}
<ITEM_LIST>, return COMMA;
<ITEM_LIST>[ \t]+ ;
<ITEM_LIST>[ \t]*\r?\n { BEGIN(INITIAL); }
<MNAME>[\ \t\r]*\n { BEGIN(INITIAL); }
<MNAME>[^,\ \t\r\n][^,\r\n]+[^,\ \t\r\n] {
settext();
return MONSTER_NAME;
}
<MNAME>, return COMMA;
<MNAME>[ \t\r]+ ;
<ARGUMENT>{NSPACE}.*{NSPACE} {
BEGIN(INITIAL);
settext();
return STRING;
}
<ARGUMENT>\r?\n { BEGIN(INITIAL); }
<TOEOL>.*\\[ \t]*$ {
settext(true, 1);
return STRING;
}
<TOEOL>.+$ {
BEGIN(INITIAL);
settext();
return STRING;
}
<TOEOL>\r?\n ;
^[ \t]*#.* ;
^\s*MAP[ \t]*$ { BEGIN(MAPDEF); }
^[ \t]*: { BEGIN(LUA_ONELINER); return MAIN; }
^[ \t]*prelude[ \t]*\{\{ { BEGIN(LUA); return PRELUDE; }
^[ \t]*lua[ \t]*\{\{ { BEGIN(LUA); return MAIN; }
^[ \t]*\{\{ { BEGIN(LUA); return MAIN; }
^[ \t]*validate[ \t]*\{\{ { BEGIN(LUA); return VALIDATE; }
^[ \t]*veto[ \t]*\{\{ { BEGIN(LUA); return VETO; }
NAME: { BEGIN(ARGUMENT); return NAME; }
default-depth: { BEGIN(ARGUMENT); return DEFAULT_DEPTH; }
DEPTH: { BEGIN(ARGUMENT); return DEPTH; }
ORIENT: { BEGIN(ARGUMENT); return ORIENT; }
PLACE: { BEGIN(ARGUMENT); return PLACE; }
WELCOME: { BEGIN(ARGUMENT); return WELCOME; }
CHANCE: return CHANCE;
WEIGHT: return CHANCE;
FLAGS: { BEGIN(KEYWORDS); return TAGS; }
TAGS: { BEGIN(KEYWORDS); return TAGS; }
LFLAGS: { BEGIN(ARGUMENT); return LFLAGS; }
BFLAGS: { BEGIN(ARGUMENT); return BFLAGS; }
SUBST: { BEGIN(ITEM_LIST); return SUBST; }
NSUBST: { BEGIN(ITEM_LIST); return NSUBST; }
COLOUR: { BEGIN(ITEM_LIST); return COLOUR; }
FLOORCOL: { BEGIN(ARGUMENT); return FLOORCOL; }
ROCKCOL: { BEGIN(ARGUMENT); return ROCKCOL; }
MONS: { BEGIN(MNAME); return MONS; }
ITEM: { BEGIN(ITEM_LIST); return ITEM; }
MARKER: { BEGIN(TOEOL); return MARKER; }
SHUFFLE: { BEGIN(ITEM_LIST); return SHUFFLE; }
KFEAT: { BEGIN(ARGUMENT); return KFEAT; }
KITEM: { BEGIN(ARGUMENT); return KITEM; }
KMONS: { BEGIN(ARGUMENT); return KMONS; }
KMASK: { BEGIN(ARGUMENT); return KMASK; }
, return COMMA;
[0-9]+ {
clean();
yylval.i = atoi(yytext);
return INTEGER;
}
[\ \t]+ ;
\r?\n ;
. return CHARACTER;
%%
int yywrap()
{
clean();
flush_free_queue(0);
return 1;
}
|
