From 60c5f48aff6a579ce22bd4b4245f7be346609901 Mon Sep 17 00:00:00 2001
From: Jesse Luehrs <doy@tozt.net>
Date: Tue, 15 Jun 2010 01:36:37 -0500
Subject: convert to new dzil stuff

---
 t/22-replaced-constructor.t | 62 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 t/22-replaced-constructor.t

(limited to 't/22-replaced-constructor.t')

diff --git a/t/22-replaced-constructor.t b/t/22-replaced-constructor.t
new file mode 100644
index 0000000..c7b2e44
--- /dev/null
+++ b/t/22-replaced-constructor.t
@@ -0,0 +1,62 @@
+#!/usr/bin/env perl
+use strict;
+use warnings;
+use Test::More tests => 7;
+
+our $foo_constructed = 0;
+
+package Foo;
+
+sub new {
+    my $class = shift;
+    bless {}, $class;
+}
+
+package Foo::Moose;
+use Moose;
+use MooseX::NonMoose;
+extends 'Foo';
+
+after new => sub {
+    $main::foo_constructed = 1;
+};
+
+package Foo::Moose2;
+use Moose;
+use MooseX::NonMoose;
+extends 'Foo';
+
+sub new {
+    my $class = shift;
+    $main::foo_constructed = 1;
+    return $class->meta->new_object(@_);
+}
+
+package main;
+my $method = Foo::Moose->meta->get_method('new');
+isa_ok($method, 'Class::MOP::Method::Wrapped');
+my $foo = Foo::Moose->new;
+ok($foo_constructed, 'method modifier called for the constructor');
+$foo_constructed = 0;
+{
+    # we don't care about the warning that moose isn't going to inline our
+    # constructor - this is the behavior we're testing
+    local $SIG{__WARN__} = sub {};
+    Foo::Moose->meta->make_immutable;
+}
+is($method, Foo::Moose->meta->get_method('new'),
+   'make_immutable doesn\'t overwrite constructor with method modifiers');
+$foo = Foo::Moose->new;
+ok($foo_constructed, 'method modifier called for the constructor (immutable)');
+
+$foo_constructed = 0;
+$method = Foo::Moose2->meta->get_method('new');
+$foo = Foo::Moose2->new;
+ok($foo_constructed, 'custom constructor called');
+$foo_constructed = 0;
+# still need to specify inline_constructor => 0 when overriding new manually
+Foo::Moose2->meta->make_immutable(inline_constructor => 0);
+is($method, Foo::Moose2->meta->get_method('new'),
+   'make_immutable doesn\'t overwrite custom constructor');
+$foo = Foo::Moose2->new;
+ok($foo_constructed, 'custom constructor called (immutable)');
-- 
cgit v1.2.3-54-g00ecf