summaryrefslogtreecommitdiffstats
path: root/t/20-BUILD.t
blob: d5cc68fc2c82ffc83c1805cda8ba05e5420aab19 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
#!/usr/bin/env perl
use strict;
use warnings;
use Test::More;

package Foo;

sub new {
    my $class = shift;
    bless { foo => 'FOO' }, $class;
}

package Foo::Moose;
use Moose;
use MooseX::NonMoose;
extends 'Foo';

has class => (
    is => 'rw',
);

has accum => (
    is      => 'rw',
    isa     => 'Str',
    default => '',
);

sub BUILD {
    my $self = shift;
    $self->class(ref $self);
    $self->accum($self->accum . 'a');
}

package Foo::Moose::Sub;
use Moose;
extends 'Foo::Moose';

has bar => (
    is => 'rw',
);

sub BUILD {
    my $self = shift;
    $self->bar('BAR');
    $self->accum($self->accum . 'b');
}

package main;
my $foo_moose = Foo::Moose->new;
is($foo_moose->class, 'Foo::Moose', 'BUILD method called properly');
is($foo_moose->accum, 'a', 'BUILD method called properly');

my $foo_moose_sub = Foo::Moose::Sub->new;
is($foo_moose_sub->class, 'Foo::Moose::Sub', 'parent BUILD method called');
is($foo_moose_sub->bar, 'BAR', 'child BUILD method called');
is($foo_moose_sub->accum, 'ab', 'BUILD methods called in the correct order');

done_testing;