basic_escape_char = @{ "\\\\" | "\\'" }
escape_char       = @{ "\\" ~ ANY }

bareword_char = @{
    escape_char |
    !("|" | ";" | "\"" | "'" | "$" | WHITESPACE | COMMENT) ~ ANY
}
single_string_char = @{ basic_escape_char | (!"'" ~ ANY) }
double_string_char = @{ escape_char | (!"\"" ~ ANY) }

var = @{
    ("$" ~ XID_START ~ XID_CONTINUE*) |
    ("$" ~ ("?" | "$" | "*" | ASCII_DIGIT)) |
    ("${" ~ (!"}" ~ ANY)+ ~ "}")
}

redir_prefix  = @{ ASCII_DIGIT* ~ (">>" | ">" | "<") ~ WHITESPACE* }
bareword      = @{ bareword_char+ }
single_string = @{ single_string_char+ }
double_string = @{ double_string_char+ }

word     = ${
    redir_prefix? ~
    (var | bareword |
    "'" ~ single_string ~ "'" |
    "\"" ~ (var | double_string)+ ~ "\"")+
}

exe      = ${ word ~ (w ~ word)* }
list     = ${ word ~ (w ~ word)* }
pipeline = ${ exe ~ (w? ~ "|" ~ w? ~ exe)* }

control_if    = ${ "if" ~ w ~ pipeline }
control_while = ${ "while" ~ w ~ pipeline }
control_for   = ${ "for" ~ w ~ bareword ~ w ~ "in" ~ w ~ list }
control_end   = ${ "end" }
control       = ${ control_if | control_while | control_for | control_end }

command  = ${ control | pipeline }
commands = ${ command ~ (w? ~ ";" ~ w? ~ command)* }

line = ${ SOI ~ w? ~ commands ~ w? ~ EOI }

w          = _{ (WHITESPACE | COMMENT)+ }
WHITESPACE = _{ (" " | "\t" | "\n") }
COMMENT    = _{ "#" ~ ANY* }