From 25b489a34ad55818a7407ce32f3c89968a1d240f Mon Sep 17 00:00:00 2001
From: Jesse Luehrs <doy@tozt.net>
Date: Thu, 29 Sep 2011 03:36:13 -0500
Subject: remove test numbers

---
 t/basic.t | 88 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 88 insertions(+)
 create mode 100644 t/basic.t

(limited to 't/basic.t')

diff --git a/t/basic.t b/t/basic.t
new file mode 100644
index 0000000..a9d238c
--- /dev/null
+++ b/t/basic.t
@@ -0,0 +1,88 @@
+#!/usr/bin/env perl
+use strict;
+use warnings;
+use Test::More;
+use Plack::Test;
+use FindBin;
+
+use HTTP::Request::Common;
+use Path::Class ();
+
+{
+    package Foo::Controller;
+    use Moose;
+
+    has view => (
+        is       => 'ro',
+        isa      => 'OX::View::TT',
+        required => 1,
+        handles  => ['render'],
+    );
+
+    our $AUTOLOAD;
+    sub AUTOLOAD {
+        my $self = shift;
+        my ($r) = @_;
+        (my $template = $AUTOLOAD) =~ s/.*:://;
+        $template .= '.tt';
+        my $defaults = $r->env->{'plack.router.match'}->mapping;
+        $self->render($r, $template, $defaults);
+    }
+    sub can { 1 }
+}
+
+{
+    package Foo;
+    use OX;
+
+    has template_root => (
+        is    => 'ro',
+        isa   => 'Str',
+        block => sub {
+            Path::Class::dir($FindBin::Bin)->subdir('data', 'basic', 'templates')->stringify
+        },
+    );
+
+    has view => (
+        is           => 'ro',
+        isa          => 'OX::View::TT',
+        dependencies => ['template_root'],
+    );
+
+    has root => (
+        is           => 'ro',
+        isa          => 'Foo::Controller',
+        dependencies => ['view'],
+    );
+
+    router as {
+        route '/' => 'root.index', (
+            content => 'Hello world',
+        );
+        route '/foo' => 'root.foo';
+    };
+}
+
+my $foo = Foo->new;
+my $view = $foo->view;
+isa_ok($view, 'OX::View::TT');
+isa_ok($view->tt, 'Template');
+
+test_psgi
+    app => $foo->to_app,
+    client => sub {
+        my $cb = shift;
+
+        {
+            my $res = $cb->(GET 'http://localhost/');
+            is($res->code, 200, "right code");
+            is($res->content, "<b>Hello world</b>\n", "right content");
+        }
+        {
+            my $res = $cb->(GET 'http://localhost/foo');
+            is($res->code, 200, "right code");
+            is($res->content, "<p>/foo</p>\n", "right content");
+        }
+    };
+
+done_testing;
-- 
cgit v1.2.3-54-g00ecf