From f86a68225d9a06750d75a25a1de9f194a35ee523 Mon Sep 17 00:00:00 2001
From: Jesse Luehrs <doy@tozt.net>
Date: Fri, 28 Dec 2012 15:40:25 -0600
Subject: implement wire_names

---
 lib/Bread/Board.pm |  4 +++
 t/024_sugar.t      | 83 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 87 insertions(+)
 create mode 100644 t/024_sugar.t

diff --git a/lib/Bread/Board.pm b/lib/Bread/Board.pm
index 8c965ba..1132fd3 100644
--- a/lib/Bread/Board.pm
+++ b/lib/Bread/Board.pm
@@ -447,4 +447,8 @@ multi service (Parcel $params) {
     service(|$params.hash);
 }
 
+sub wire_names (*@names) is export {
+    return @names.map(-> $name { $name => depends_on($name) }).hash;
+}
+
 # vim:ft=perl6:foldmethod=manual
diff --git a/t/024_sugar.t b/t/024_sugar.t
new file mode 100644
index 0000000..71e300c
--- /dev/null
+++ b/t/024_sugar.t
@@ -0,0 +1,83 @@
+use v6;
+use Test;
+
+use Bread::Board;
+
+class FileLogger {
+    has $.log_file;
+}
+
+class DBI {
+    has Str ($.dsn, $.username, $.password);
+
+    method connect (Str $dsn, Str $username, Str $password) {
+        self.new(dsn => $dsn, username => $username, password => $password);
+    }
+}
+
+class MyApplication {
+    has FileLogger $.logger;
+    has DBI $.dbh;
+}
+
+my $c = container 'MyApp', {
+    service 'log_file', 'logfile.log';
+    service 'logger', (
+        class        => FileLogger,
+        lifecycle    => Singleton,
+        dependencies => [
+            depends_on('log_file'),
+        ],
+    );
+
+    container 'Database', {
+        service 'dsn', 'dbi:sqlite:dbname=my-app.db';
+        service 'username', 'user';
+        service 'password', 'pass';
+
+        service 'dbh', (
+            block => -> $s {
+                DBI.connect(
+                    $s.param('dsn'),
+                    $s.param('username'),
+                    $s.param('password')
+                ) || die "Could not connect";
+            },
+            dependencies => wire_names(qw[dsn username password]),
+        );
+    };
+
+    service 'application', (
+        class        => MyApplication,
+        dependencies => {
+            logger => depends_on('logger'),
+            dbh    => depends_on('Database/dbh'),
+        },
+    );
+};
+
+my $logger = $c.resolve(service => 'logger');
+isa_ok($logger, FileLogger);
+is($logger.log_file, 'logfile.log');
+
+is($c.fetch('logger/log_file').service, $c.fetch('log_file'));
+is($c.fetch('logger/log_file').get, 'logfile.log');
+
+my $dbh = $c.resolve(service => 'Database/dbh');
+isa_ok($dbh, DBI);
+is($dbh.dsn, 'dbi:sqlite:dbname=my-app.db');
+is($dbh.username, 'user');
+is($dbh.password, 'pass');
+
+my $app = $c.resolve(service => 'application');
+isa_ok($app, MyApplication);
+
+isa_ok($app.logger, FileLogger);
+is($app.logger, $logger);
+
+isa_ok($app.dbh, DBI);
+isnt($app.dbh, $dbh);
+
+done;
+
+# vim:ft=perl6:foldmethod=manual
-- 
cgit v1.2.3