lib/Reply/Plugin/Autocomplete/Methods.pm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

package main;
use strict;
use warnings;
# ABSTRACT: tab completion for methods

use mop;

use Scalar::Util 'blessed';

use Reply::Util qw($ident_rx $fq_ident_rx $fq_varname_rx methods);

=head1 SYNOPSIS

  ; .replyrc
  [ReadLine]
  [Autocomplete::Methods]

=head1 DESCRIPTION

This plugin registers a tab key handler to autocomplete method names in Perl
code.

=cut

class Reply::Plugin::Autocomplete::Methods extends Reply::Plugin {
    method tab_handler ($line) {
        my ($invocant, $method_prefix) = $line =~ /($fq_varname_rx|$fq_ident_rx)->($ident_rx)?$/;
        return unless $invocant;
        # XXX unicode
        return unless $invocant =~ /^[\$A-Z_a-z]/;

        $method_prefix = '' unless defined $method_prefix;

        my $class;
        if ($invocant =~ /^\$/) {
            # XXX should support globals here
            my $env = {
                map { %$_ } $self->publish('lexical_environment'),
            };
            my $var = $env->{$invocant};
            return unless $var && ref($var) eq 'REF' && blessed($$var);
            $class = blessed($$var);
        }
        else {
            $class = $invocant;
        }

        my @results;
        for my $method (methods($class)) {
            push @results, $method if index($method, $method_prefix) == 0;
        }

        return sort @results;
    }
}

1;