blob: eb69f96055dbdbef04d125febf754dffe775214f (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
package Reply::Plugin::Packages;
use strict;
use warnings;
# ABSTRACT: persist the current package between lines
use base 'Reply::Plugin';
=head1 SYNOPSIS
; .replyrc
[Packages]
default_package = My::Scratchpad
=head1 DESCRIPTION
This plugin persists the state of the current package between lines. This
allows lines such as C<package Foo;> in the Reply shell to do what you'd
expect. The C<default_package> configuration option can also be used to set the
initial package to use when Reply starts up.
=cut
sub new {
my $class = shift;
my %opts = @_;
my $self = $class->SUPER::new(@_);
$self->{package} = $opts{default_package} || 'main';
return $self;
}
sub mangle_line {
my $self = shift;
my ($line) = @_;
my $package = __PACKAGE__;
return <<LINE;
package $self->{package};
$line
;
BEGIN {
\$${package}::package = __PACKAGE__;
}
LINE
}
sub compile {
my $self = shift;
my ($next, @args) = @_;
# XXX it'd be nice to avoid using globals here, but we can't use
# eval_closure's environment parameter since we need to access the
# information in a BEGIN block
our $package = $self->{package};
my @result = $next->(@args);
$self->{package} = $package;
return @result;
}
1;
|