1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
|
package Bread::Board::Declare::Meta::Role::Attribute;
use Moose::Role;
Moose::Util::meta_attribute_alias('Service');
# ABSTRACT: attribute metarole for Bread::Board::Declare
use Bread::Board::Types;
use List::MoreUtils qw(any);
use Bread::Board::Declare::BlockInjection;
use Bread::Board::Declare::ConstructorInjection;
use Bread::Board::Declare::Literal;
=head1 DESCRIPTION
This role adds functionality to the attribute metaclass for
L<Bread::Board::Declare> objects.
=cut
=attr service
Whether or not to create a service for this attribute. Defaults to true.
=cut
has service => (
is => 'ro',
isa => 'Bool',
default => 1,
);
=attr block
The block to use when creating a L<Bread::Board::BlockInjection> service.
=cut
has block => (
is => 'ro',
isa => 'CodeRef',
predicate => 'has_block',
);
=attr literal_value
The value to use when creating a L<Bread::Board::Literal> service. Note that
the parameter that should be passed to C<has> is C<value>.
=cut
# has_value is already a method
has literal_value => (
is => 'ro',
isa => 'Value',
init_arg => 'value',
predicate => 'has_literal_value',
);
=attr lifecycle
The lifecycle to use when creating the service. See L<Bread::Board::Service>
and L<Bread::Board::LifeCycle>.
=cut
has lifecycle => (
is => 'ro',
isa => 'Str',
predicate => 'has_lifecycle',
);
=attr dependencies
The dependency specification to use when creating the service. See
L<Bread::Board::Service::WithDependencies>.
=cut
has dependencies => (
is => 'ro',
isa => 'Bread::Board::Service::Dependencies',
coerce => 1,
predicate => 'has_dependencies',
);
=attr parameters
The parameter specification to use when creating the service. See L<Bread::Board::Service::WithParameters>.
=cut
has parameters => (
is => 'ro',
isa => 'Bread::Board::Service::Parameters',
coerce => 1,
predicate => 'has_parameters',
);
=attr infer
If true, the dependency list will be inferred as much as possible from the
attributes in the class. See L<Bread::Board::Manual::Concepts::Typemap> for
more information. Note that this is only valid for constructor injection
services.
=cut
has infer => (
is => 'ro',
isa => 'Bool',
);
=attr constructor_name
The constructor name to use when creating L<Bread::Board::ConstructorInjection>
services. Defaults to C<new>.
=cut
has constructor_name => (
is => 'ro',
isa => 'Str',
predicate => 'has_constructor_name',
);
=attr associated_service
The service object that is associated with this attribute.
=cut
has associated_service => (
is => 'rw',
does => 'Bread::Board::Service',
predicate => 'has_associated_service',
);
after attach_to_class => sub {
my $self = shift;
return unless $self->service;
my %params = (
associated_attribute => $self,
name => $self->name,
($self->has_lifecycle
? (lifecycle => $self->lifecycle)
: ()),
($self->has_dependencies
? (dependencies => $self->dependencies)
: ()),
($self->has_parameters
? (parameters => $self->parameters)
: ()),
($self->has_constructor_name
? (constructor_name => $self->constructor_name)
: ()),
);
my $tc = $self->has_type_constraint ? $self->type_constraint : undef;
my $service;
if ($self->has_block) {
if ($tc && $tc->isa('Moose::Meta::TypeConstraint::Class')) {
%params = (%params, class => $tc->class);
Class::MOP::load_class($tc->class);
}
$service = Bread::Board::Declare::BlockInjection->new(
%params,
block => $self->block,
);
}
elsif ($self->has_literal_value) {
$service = Bread::Board::Declare::Literal->new(
%params,
value => $self->literal_value,
);
}
elsif ($tc && $tc->isa('Moose::Meta::TypeConstraint::Class')) {
Class::MOP::load_class($tc->class);
$service = Bread::Board::Declare::ConstructorInjection->new(
%params,
class => $tc->class,
);
}
else {
$service = Bread::Board::Declare::BlockInjection->new(
%params,
block => sub {
die "Attribute " . $self->name . " did not specify a service."
. " It must be given a value through the constructor or"
. " writer method before it can be resolved."
},
);
}
$self->associated_service($service) if $service;
};
after _process_options => sub {
my $class = shift;
my ($name, $opts) = @_;
return unless exists $opts->{default}
|| exists $opts->{builder};
return unless exists $opts->{class}
|| exists $opts->{block}
|| exists $opts->{value};
# XXX: uggggh
return if any { $_ eq 'Moose::Meta::Attribute::Native::Trait::String'
|| $_ eq 'Moose::Meta::Attribute::Native::Trait::Counter' }
@{ $opts->{traits} };
my $exists = exists($opts->{default}) ? 'default' : 'builder';
die "$exists is not valid when Bread::Board service options are set";
};
around get_value => sub {
my $orig = shift;
my $self = shift;
my ($instance) = @_;
return $self->$orig($instance)
if $self->has_value($instance);
my $val = $instance->get_service($self->name)->get;
if ($self->has_type_constraint) {
$val = $self->type_constraint->coerce($val)
if $self->should_coerce;
$self->verify_against_type_constraint($val, instance => $instance);
}
if ($self->should_auto_deref) {
if (ref($val) eq 'ARRAY') {
return wantarray ? @$val : $val;
}
elsif (ref($val) eq 'HASH') {
return wantarray ? %$val : $val;
}
else {
die "Can't auto_deref $val.";
}
}
else {
return $val;
}
};
if (Moose->VERSION > 1.9900) {
around _inline_instance_get => sub {
my $orig = shift;
my $self = shift;
my ($instance) = @_;
return 'do {' . "\n"
. 'my $val;' . "\n"
. 'if (' . $self->_inline_instance_has($instance) . ') {' . "\n"
. '$val = ' . $self->$orig($instance) . ';' . "\n"
. '}' . "\n"
. 'else {' . "\n"
. '$val = ' . $instance . '->get_service(\'' . $self->name . '\')->get;' . "\n"
. join("\n", $self->_inline_check_constraint(
'$val',
'$type_constraint',
(Moose->VERSION >= 2.0100
? '$type_message'
: '$type_constraint_obj'),
)) . "\n"
. '}' . "\n"
. '$val' . "\n"
. '}';
};
}
else {
around accessor_metaclass => sub {
my $orig = shift;
my $self = shift;
return Moose::Meta::Class->create_anon_class(
superclasses => [ $self->$orig(@_) ],
roles => [ 'Bread::Board::Declare::Meta::Role::Accessor' ],
cache => 1
)->name;
};
}
no Moose::Role;
1;
|
