bin/explode_csv


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

#!/usr/bin/env perl
use strict;
use warnings;

use Spreadsheet::ParseExcel;
use Text::CSV;

my $filename = $ARGV[0];

my $parser = Spreadsheet::ParseExcel->new;
my $wb = $parser->parse($filename) || die $parser->error;

(my $dir = $filename) =~ s/\.[^.]*$//;
mkdir $dir;
chdir $dir;

for my $ws ($wb->worksheets) {
    my $csv = Text::CSV->new({ binary => 1, eol => "\n" });
    my $filename = $ws->get_name . '.csv';
    open my $fh, '>:encoding(UTF-8)', $filename
        or die "Couldn't open $filename: $!";

    my ($rmin, $rmax) = $ws->row_range;
    my ($cmin, $cmax) = $ws->col_range;

    for my $row (0..$rmin - 1) {
        $csv->print($fh, [ ('') x ($cmax + 1) ]);
    }

    for my $row ($rmin..$rmax) {
        my @row = (('') x $cmin);
        for my $col ($cmin..$cmax) {
            my $cell = $ws->get_cell($row, $col);
            push @row, $cell ? $cell->value : '';
        }
        $csv->print($fh, \@row);
    }

    close $fh
        or die "Couldn't close $filename: $!";
}