New Crypt:5 map (Neil Middleton).

1 files changed, 157 insertions, 1 deletions

diff --git a/crawl-ref/source/dat/crypt.des b/crawl-ref/source/dat/crypt.des
index 61669a3784..1587ed5cf2 100644
--- a/crawl-ref/source/dat/crypt.des
+++ b/crawl-ref/source/dat/crypt.des
@@ -588,7 +588,7 @@ NAME:   david_glass_crypt
 ORIENT: float
 TAGS:   no_item_gen no_rotate
 PLACE:  Crypt:5
-SUBST:  m : mn
+SUBST:  m : mnn
 MONS:   lich / ancient lich
 MONS:   skeletal dragon / curse skull / curse toe
 MONS:   flying skull / skeletal warrior / w:40 nothing
@@ -616,6 +616,162 @@ MAP
 ENDMAP
 
 ##############################################################################
+#       Four quadrants (by mu)
+#       burial horde (NE), chapel of kikubaaqudgha (NW), catacombs (SE), crematory (SW)
+#
+NAME:   quadcrypt_mu
+ORIENT: encompass
+TAGS:   no_monster_gen no_item_gen no_pool_fixup no_rotate no_vmirror no_hmirror
+PLACE:  Crypt:5
+WEIGHT: 10000
+####### chapel garden
+SUBST:  F = f ?
+SUBST:  f = p:1 .:1
+KFEAT:  p = .
+KMONS:  p = w:2 col:darkgrey plant / w:1 col:lightgrey plant
+####### hidden skeleton; sometimes good pain weapon, but draining short sword
+KFEAT:  ! = .
+KMONS:  ! = skeletal warrior ; w:2 dagger ego:pain | short sword ego:draining |\
+                               w:2 sabre ego:pain | w:1 quick blade ego:pain
+KFEAT:  A = .
+KFEAT:  D = .
+KFEAT:  E = .
+KFEAT:  G = .
+KFEAT:  H = .
+KFEAT:  I = .
+KFEAT:  J = .
+KFEAT:  P = .
+KFEAT:  Z = .
+KFEAT:  Q = .
+KFEAT:  R = .
+KFEAT:  S = .
+KFEAT:  t = .
+KFEAT:  X = .
+KFEAT:  b = .
+KFEAT:  8 = .
+KFEAT:  o = granite_statue
+KFEAT:  _ = altar_kikubaaqudgha
+KFEAT:  ~ = bolt trap / blade trap / needle trap / axe trap
+SUBST:  s = v =
+SUBST:  B = b %
+KITEM:  b = any book
+SUBST:  ? = $ % * |:1
+SUBST:  u = U Y
+SUBST:  ; = ..~
+KMONS:  8 = iron golem
+####### NW monsters (chapel).
+KMONS:  A = ancient lich / w:2 mummy priest
+KMONS:  D = lich / w:5 ancient lich
+KMONS:  E = iron golem
+KMONS:  G = flayed ghost / hungry ghost / phantom
+####### NE monsters (horde). On a coinflip, either vampires or mummies.
+: if crawl.coinflip() == 0 then
+KMONS:  H = vampire mage
+KMONS:  I = vampire knight
+KMONS:  J = vampire
+KMONS:  P = large zombie / small zombie / large skeleton / small skeleton
+: else
+KMONS:  H = sphinx
+KMONS:  I = guardian mummy
+KMONS:  J = guardian mummy / mummy
+KMONS:  P = large skeleton / mummy
+: end
+####### SE monsters (catacombs). Either corporeal or incorporeal undead.
+: if crawl.coinflip() == 0 then
+KMONS:  Z = curse skull
+KMONS:  Q = skeletal dragon
+KMONS:  R = skeletal warrior
+KMONS:  S = large zombie / small zombie / large skeleton / small skeleton
+: else
+KMONS:  Z = curse skull
+KMONS:  Q = spectral iron dragon
+KMONS:  R = spectral warrior
+KMONS:  S = phantom / wraith / freezing wraith / flayed ghost / wight
+: end
+####### SW monsters (crematory). Either fiery undead or hellish.
+: if crawl.coinflip() == 0 then
+KMONS:  t = w:20 flaming corpse / fire giant skeleton / dragon skeleton
+KMONS:  X = w:1 curse skull / w:19 flaming corpse
+: else
+KMONS:  t = w:20 hell knight / smoke demon / red devil
+KMONS:  X = w:1 curse skull / w:19 hell knight
+: end
+####### Randomisation of secret doors; there is a chance of no door at all.
+SUBST:  K : Kvvv
+SUBST:  ' : 'vvv
+SUBST:  " : "v
+NSUBST: K = 1:= / *:v
+NSUBST: ' = 1:= / *:v
+NSUBST: " = 1:= / *:v
+MAP
+vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv
+vccccccccccccccccccccccccc......"...Bvvvvvvvvvvvvvvvvvvvvvv
+vc..D..c.....c....Bc;;+;;c.ffff.vvvBDvvvvvvvvvvvvvvvvvvvvvv
+vc.c.c.+.....+....cc;;+;;c.ffFf.vvvv"vvvvvvvvvvvvvnP=.....v
+vc.._..+...D.c....Bc;;c;;m.ffFf.v????||$$$.vvvvv..nPn|????v
+vc.c.c.c.....c....cc..c..c.ffff.v$$$$$$$$$.vvvv...nPn$$$$$v
+vc.....ccc=ccc....Bc..cGGc.ffff.vnnnnnnnnn=vvv..H.nPn$$$$$v
+vc.....c.....c....cc..c..c.ffff.v;;;;;;;;;;vv.....nPn$$$$$v
+vc.....c?....c..A.Bc..c..m..fff.v;;;;;;;;;;vv.uvu.nPn$$$$$v
+vc.....c|?...c....cc..c..c...ff.v;;vvvvvvvvv..vvv.nPnnnnnnv
+vc.....c||?EEcBcBcc...c..c....f.v;;;;;;;;;;+..uvu.nPPPPPPPv
+vc++cccccccccccccc...cc..c......v;;;;;;;;;;+......nnnnnnn=v
+vc.....G............cc...m..G...vvvvvvvvvvvv.H............v
+vc.....G...........cc...cc......v....vvvvvvv..............v
+vccccccccccccccccccc...cc...ff..v.JJ...vvvvvv....v..v..v..v
+vc.....;;;;;;.........cc..fffff.v.......vvvvv.............v
+vc......;;;;.........ccE..fffff.vv+vv....vvvvv...v..v..v..v
+vccmcccmm++mmcccmcccmc...fffff..v...vvv...vvvvv...........v
+v.......f..f............fffffff.v.....vv...vvvvv..........v
+v....ffff..ffff.........fffFfff.v......v...vvvvvvvvvvvv++vv
+v.G.ffff...ffff...G....ffffffff.v......vv...v;..;.I;..;..;v
+v...ffff...fffff.......fffffff..v.......v...+.;..;..;..;..v
+v....ffff....ffff.......f.ffff..v.......v...+..;..;..;..;.v
+v......f.f....ffff..............v.......v...v;..;.I;..;..;v
+vvvvvvvvvvvvvv==vvvvvvvvvvvvvvvvvvvvvvv=vvvvvvvvvvvvvvvvvvv
+vvvvvvvvvvvvv....v??llv??llv??llvvvvvvo.ovvvWWWWWWW.......v
+vvvvvlllvvvvv....v?.tlv?.tlv?.tlvvvv.......vvWWWWWWZ.mmmm;v
+vvv.......vvv....v....v....v....vvv.........vvWWWWWWWm*|m.v
+vv.........vv....v....v....v....vv...........vWWWWWWWW*|m;v
+v..ccc.ccc..vv++vvv==vvv==vvv==vvv...R.Q.R...vvWWWWmWW%|m.v
+v...lc.cl...v...................vo...........ovWWWWmmmmmm;v
+v..t.c.c.t..+.;;;;;;;;;;;;;;;;;.=......U......=...........v
+v...........v...................vo...........ov...........v
+v.cccc.cccc.vvvvvvvvvKvvvvvvvvvvvv.........vvvvvvvvvvvvvvvv
+v.cll...llc.v??......<vvvvvvvvvvvv.........+..;=..........v
+v.clt...tlc.K???.....Kvvvvvvvvvvvvv........+.;.vvvvvvvvvv.v
+v.c...X...c.v????|KKvvwwwwwwwwvvvvvv.......v;...vvvW.R.%v.v
+v...........vRRRRKvwwwwwwwwwwwwwwvvvvvo.ovvv=v...vvW...%v.v
+v..ccc.ccc..vRRKvvwwwwwwwwwwwwwwwwvvvvv=vvvv.vv...vv...$v.v
+v..lc...cl..vvvvwwwwwwwwwwwwwwwwwwwwvvv<v....vvv...vvv=vv.v
+v.t.......t.vvvwwwwwwwwwwwwwwwwwwwwwwvvvv.vvvvvvv...vv....v
+v....lll....vvvwwwwwwwwwwwwwwwwwwwwwwvvvv.v%RWvvvv...vvvv.v
+v....lml....vvwwwwwwwwwwwwwwwwwwwwwwwwvvv.v..Wvvvvv...vvv.v
+v....lll....vwwwwwwwwwwwwwwwwwwwwwwwwwwvv.v.vvvvvvvv...vv.v
+v...........vwwwwwwwwwwwwwwwwwwwwwwwwwwvv.v.v%R.Wv%vv...vvv
+vvvv++vvvvvvvwwwwwww..8..wwwwwwwwwwwwwwvv.v.v...WvRWvv...vv
+v........stvwwwwww.........wwwwwwwwwwwwwv.v=v=vvvv=vvvv...v
+v...ll...vsvwwwww...........wwwwwwwwwwwwv............vvv..v
+v...ll...stvwwww.............wwwwwwwwwwwvvvvvvvvvvvvvvvvv+v
+v...ll...vsvwwww.............wwww..;;.;;+.;;.....R......v.v
+v...ll...stvwww...............ww...;;.;;+.;;.V.S.R.V....v.v
+v.llllll.vsvwww...................wwwwwwv.;;...S........v.v
+v.llllll.stvwww8.............8...wwwwwwwv.;;.V.S.R.V....v.v
+v...ll...vsvwww.................wwwwwwwwv.;;.....R......v.v
+v.t.ll...vtvvww...............wwwwwwwwwvvvvvv''vvvvvvv+vv+v
+v.t.ll...v.*vwww.{...........wwwwwwwwwwv...;...'o$.....vv.v
+v...ll...v.%vwww..[..........wwwwwwwwwwv....;..v$;....vvv.v
+v........=.*vvwww..(........wwwwwwwwwwvv..W..;.v..;..vvv..v
+vvvvvvvvvvvvvvvwww.........wwwwwwwwwwvv..SW...;v.S.;vvv.S.v
+vvvvvvvvvvvvvvvwwwww..8..wwwwwwwwwwwwv;.WWWWW..'...vvv;...v
+vvvvvvvvvvvvvvvvwwwwwwwwwwwwwwwwwwwwvv.;..W....v..vvv..;..v
+vvvvvvvvvvvvvvvvvvwwwwwwwwwwwwwwwwvvv...;.W....v+vvv....;$v
+vvvvvvvvvvvvvvvvvvvwwwwwwwwwwwwwwvv!s....;..R..'........$ov
+vvvvvvvvvvvvvvvvvvvvvvwwwwwwwwvvvvvvvvvvvvvvvvvvvvvvvvvvvvv
+vvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvvv
+ENDMAP
+
+##############################################################################
 # The three Tomb levels: these should generally be of a confusing layout.
 ##############################################################################