nicolae vaults (#8745).

Dithmenos vaults have been edited to not use darkgray and not smoke out
the altar 100% of the time, and there are a couple of minor formatting
fixes as well.

4 files changed, 302 insertions, 0 deletions

diff --git a/crawl-ref/source/dat/des/altar/overflow.des b/crawl-ref/source/dat/des/altar/overflow.des
index 26c642cce5..10b08f50dd 100644
--- a/crawl-ref/source/dat/des/altar/overflow.des
+++ b/crawl-ref/source/dat/des/altar/overflow.des
@@ -356,6 +356,81 @@ c...c
 cc+cc
 ENDMAP
 
+NAME: nicolae_dithmenos_the_darkroom
+TAGS: temple_overflow_dithmenos temple_overflow_1 uniq_altar_dithmenos
+TAGS: decor transparent
+DEPTH: D:4-
+KFEAT: _ = altar_dithmenos
+MARKER: ' = lua:fog_machine { cloud_type = "black smoke", pow_min = 30, \
+   pow_max = 50, delay_min = 50, delay_max = 90, size = 1, walk_dist = 1, \
+   spread_rate = 10 }
+: interest_check(_G)
+MAP
+xxxx@@@xxxx
+xxx.....xxx
+xx'.....'xx
+x.........x
+@.........@
+@...._....@
+@.........@
+x.........x
+xx'.....'xx
+xxx.....xxx
+xxxx@@@xxxx
+ENDMAP
+
+NAME: nicolae_dithmenos_shadow_blocks
+TAGS: temple_overflow_dithmenos temple_overflow_1 uniq_altar_dithmenos
+TAGS: decor transparent
+DEPTH: D:2-
+COLOUR: s' = magenta, c = white
+TILE: c = dngn_stone_wall_white
+TILE: s = dngn_stone_dark
+FTILE: 's_ = floor_pebble_darkgray
+KFEAT: cs = stone_wall
+KFEAT: _ = altar_dithmenos
+: interest_check(_G)
+MAP
+      .....
+      ..c..
+  .....ccc.....
+  .cc..scs..cc.
+  .ccs''s''scc.
+  ..ss'''''ss..
+....'''''''''....
+..cs'''''''''sc..
+.cccs'''_'''sccc.
+..cs'''''''''sc..
+....'''''''''....
+  ..ss'''''ss..
+  .ccs''s''scc.
+  .cc..scs..cc.
+  .....ccc.....
+      ..c..
+      .....
+ENDMAP
+
+NAME: nicolae_dithmenos_through_a_glass_darkly
+TAGS: temple_overflow_dithmenos uniq_altar_dithmenos temple_overflow_1
+TAGS: decor transparent
+DEPTH: D:2-
+COLOUR: x = magenta, m = lightmagenta
+TILE: m = dngn_transparent_wall_darkgray
+TILE: x = wall_brick_darkgray
+KFEAT: _ = altar_dithmenos
+: interest_check(_G)
+MAP
+  ..xxx
+ .....xx
+...mm..xx
+..mm....x
+@.m._...x
+..mm....x
+...mm..xx
+ .....xx
+  ..xxx
+ENDMAP
+
 ### Elyvilon overflow altars ##################################################
 
 NAME:   elyvilon_altar_1
@@ -2338,6 +2413,97 @@ MAP
      ....
 ENDMAP
 
+NAME: nicolae_tso_swordbearing_angel
+TAGS: temple_overflow_the_shining_one uniq_altar_the_shining_one
+TAGS: temple_overflow_1 decor transparent
+DEPTH: D:2-
+COLOUR: . = yellow
+COLOUR: c = white
+FTILE: @._+ = floor_limestone
+TILE: c = wall_church
+KFEAT: _ = altar_the_shining_one
+: interest_check(_G)
+MAP
+     xxxxx
+    xxcccxx
+    xcc.ccx
+xxxxxc._.cxxxxx
+xcccccc.ccccccx
+xc...........cx
+xcc....v....ccx
+xxcc..vvv..ccxx
+ xxcc..v..ccxx
+  xxcc.v.ccxx
+   xxc.v.cxx
+    xc.v.cx
+    xc.v.cx
+    xc...cx
+    xcc+ccx
+ENDMAP
+
+
+NAME: nicolae_tso_carved_into_rock
+TAGS: temple_overflow_the_shining_one uniq_altar_the_shining_one
+TAGS: temple_overflow_1 transparent decor
+DEPTH: D:2-
+SUBST: X = xxx.
+COLOUR: ' = yellow
+COLOUR: c = white
+TILE: G = dngn_golden_statue
+TILE: c = wall_church
+FTILE: G'_ = floor_limestone
+KFEAT: _ = altar_the_shining_one
+: interest_check(_G)
+MAP
+xxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
+xxxxxxxxxxxxxXXXXxxxxxxxxxxxxx
+xxxxxxxXXXXXX....XXXXXXxxxxxxx
+xxxxXXX................XXXxxxx
+xxXX......................XXxx
+xX......XxX........XxX......Xx
+X.....XXxxxxcG'''GcxxxXX.....X
+.....Xxxxxxxccc'cccxxxxxX.....
+@...Xxxxxxxxxc'''cxxxxxxxX...@
+..Xxxxxxxxxxxc'_'cxxxxxxxxXX..
+XXxxxxxxxxxxxc'''cxxxxxxxxxxXX
+xxxxxxxxxxxxxcccccxxxxxxxxxxxx
+xxxxxxxxxxxxxxxxxxxxxxxxxxxxxx
+ENDMAP
+
+NAME: nicolae_tso_besieged_by_evil
+TAGS: temple_overflow_the_shining_one uniq_altar_the_shining_one
+TAGS: temple_overflow_1 patrolling transparent no_monster_gen
+DEPTH: D:4-9
+SUBST: c = ccc' s:2 z:2, + = ++'
+NSUBST: ' = 2:s / 2:z / 2:sz'' / *:'
+COLOUR: 'sz = yellow / none w:5
+COLOUR: c = white
+TILE: c = wall_sandstone
+FTILE: +'_sz = floor_sandstone / none w:5
+KMONS: s = orc skeleton / kobold skeleton / goblin skeleton / hobgoblin zombie
+KMONS: z = orc zombie / kobold zombie / goblin zombie / hobgoblin zombie
+: if you.absdepth() <= 4 then
+KMONS: _ = crimson imp / white imp w:5
+: else
+KMONS: _ = crimson imp / white imp / shadow imp / iron imp / quasit
+: end
+KFEAT: _ = altar_the_shining_one
+MAP
+.............
+.............
+..cccc.cccc..
+..cccc+cccc..
+..cc'''''cc..
+..cc'''''cc..
+...+''_''+...
+..cc'''''cc..
+..cc'''''cc..
+..cccc+cccc..
+..cccc.cccc..
+.............
+.............
+ENDMAP
+
 ### Multiple god overflow altars ###############################################
 
 # These ones are multiple overflows to specific gods;
diff --git a/crawl-ref/source/dat/des/branches/tomb.des b/crawl-ref/source/dat/des/branches/tomb.des
index 9aaf56ef63..c02ad72722 100644
--- a/crawl-ref/source/dat/des/branches/tomb.des
+++ b/crawl-ref/source/dat/des/branches/tomb.des
@@ -513,6 +513,39 @@ BBBcccccccccccc...ccccccccccccIII
              .......
 ENDMAP
 
+NAME: tomb_1_centre_nicolae_necropolis
+TAGS: tomb_1_centre unrand
+SHUFFLE: AaBbQqDd/EeFfGgHh/IiJjKkLl/MmNnOoPp/RrSsUuVv
+SHUFFLE: Aa/Bb/Qq/Dd, Ee/Ff/Gg/Hh, Ii/Jj/Kk/Ll, Mm/Nn/Oo/Pp, Rr/Ss/Uu/Vv
+SUBST: AEIMR = +, a = ), ei = *|, mr = %, bq = 4, dhlpv = 3
+SUBST: BQDFGHJKLNOPSUV = c, fgjknosu = ', ' = ~..112
+MONS: mummy / guardian mummy w:3 / nothing
+MONS: guardian mummy w:233 / ancient champion w:50 / mummy / nothing w:233
+MONS: mummy priest / lich w:1 / nothing w:11
+MONS: greater mummy / ancient lich w:1 / nothing w:11
+MAP
+.................................
+..cccAccc.....2...2.....cccEccc..
+..cc'q'cc...............cc'g'cc..
+..c'''''c...............c'''''c..
+..Db'c'dB..3.........3..Hf'c'hF..
+..c'''''c...............c'''''c..
+..cc'a'cc....cccRccc....cc'e'cc..
+..cccQccc....cc'u'cc....cccGccc..
+.............c'''''c.............
+.....3...4...Vs'c'vS...4...3.....
+.............c'''''c.............
+..cccMccc....cc'r'cc....cccIccc..
+..cc'o'cc....cccUccc....cc'k'cc..
+..c'''''c...............c'''''c..
+..Pn'c'pN..3.........3..Lj'c'kJ..
+..c'''''c...............c'''''c..
+..cc'm'cc...............cc'i'cc..
+..cccOccc.....2...2.....cccKccc..
+.................................
+             .......
+ENDMAP
+
 ####
 
 NAME:    tomb_1_hall_stairs_old
@@ -586,6 +619,49 @@ cccccccccccc''           ''cccccccccccc
 ]..11'''''''''           '''''''''11..}
 ENDMAP
 
+NAME: tomb_1_hall_stairs_nicolae_cartouches
+TAGS: tomb_1_hall_stairs unrand
+SHUFFLE: ]}
+SUBST: ' = 3 .:200
+MONS: guardian mummy w:233 / mummy / nothing w:233
+MONS: mummy priest / lich w:5 / nothing, greater mummy
+MAP
+''                                   ''
+''cc''''''cccc           cccc''''''cc''
+''c''''''''ccc           ccc''''''''c''
+'''''cccc'''cc           cc'''cccc'''''
+''''cc'''c'''c           c'''c'''cc''''
+'''cc''''1c'''           '''c1''''cc'''
+''cc]'''211c''           ''c112'''}cc''
+'''cc''''1c'''           '''c1''''cc'''
+''''cc'''c'''c           c'''c'''cc''''
+'''''cccc'''cc           cc'''cccc'''''
+''c''''''''ccc           ccc''''''''c''
+''cc''''''cccc           cccc''''''cc''
+ENDMAP
+
+NAME: tomb_1_hall_stairs_nicolae_galleries
+TAGS: tomb_1_hall_stairs unrand
+SHUFFLE: AaZ/BbY, pq
+SUBST: ADp = ', Y = 2, ad = +, BbEeq = c, ' = 3 .:200
+NSUBST: Z = ] / }
+MONS: guardian mummy w:233 / mummy / nothing w:233
+MONS: mummy priest / nothing, greater mummy
+MAP
+''                                   ''
+''BBBBBBBBBccc           cccBBBBBBBBB''
+''BBBBBBBBBccc           cccBBBBBBBBB''
+AAcccccccbbccc           cccbbcccccccAA
+AAc''qppq'Zccc           cccZ'qppq''cAA
+AAc''''1'''ccc           ccc'''1''''cAA
+AAcq'p''p'qccc           cccq'p''p'qcAA
+AAcp1'qq''pccc           cccp''qq'1pcAA
+AAcp''qq'1pccc           cccp1'qq''pcAA
+AAcq'p''p'qccc           cccq'p''p'qcAA
+AAa'''1''''ccc           ccc''''1'''aAA
+AAaY'qppq''ccc           ccc''qppq'YaAA
+ENDMAP
+
 ###############################################################################
 # Tomb:2
 #
diff --git a/crawl-ref/source/dat/des/variable/float.des b/crawl-ref/source/dat/des/variable/float.des
index d3acc8badf..4a71437b3f 100644
--- a/crawl-ref/source/dat/des/variable/float.des
+++ b/crawl-ref/source/dat/des/variable/float.des
@@ -6359,3 +6359,37 @@ llllllllll-xxlxxxxll
     llllllllllllllll
         lllllllllll
 ENDMAP
+
+NAME: nicolae_legendary_halls
+DEPTH: Depths, !Depths:$
+TAGS: transparent
+ORIENT: float
+SUBST: + : +..., $ = $$$$%*, % = %%%%$*, * = ****%|, 0 = 0009.., 9 = 998.
+MAP
+       cccc.@@.cccc
+      cc$.c....c.$cc
+     cc%..c....c..*cc
+     c$.0.c.00.c.8.$c
+     c....+....c....c
+  cccccccccccc+c+ccccccc
+ cc$.c....+....c....c.$cc
+cc*..c.9..c....c..9.c..%cc
+c$.8.c..9.c0..0c.9..c.0.$c
+c....+....c....c....c....c
+ccccccccccc....cccc+c+cccc
+.....+..0........0..c.....
+@..0.c......99......c.0..@
+@..0.c......99......c.0..@
+.....c..0........0..+.....
+cccc+c+cccc....ccccccccccc
+c....c....c....c....+....c
+c$.0.c..9.c0..0c.9..c.8.$c
+cc%..c.9..c....c..9.c..*cc
+ cc$.c....c....+....c.$cc
+  ccccccc+c+cccccccccccc
+     c....c....+....c
+     c$.8.c.00.c.0.$c
+     cc*..c....c..%cc
+      cc$.c....c.$cc
+       cccc.@@.cccc
+ENDMAP
diff --git a/crawl-ref/source/dat/des/variable/mini_features.des b/crawl-ref/source/dat/des/variable/mini_features.des
index 3d32957e8e..42464ab8d7 100644
--- a/crawl-ref/source/dat/des/variable/mini_features.des
+++ b/crawl-ref/source/dat/des/variable/mini_features.des
@@ -2627,6 +2627,32 @@ x.....wccccccw......
      ....xtx...
 ENDMAP
 
+NAME: nicolae_two_hexagons
+DEPTH: D:8-, Depths
+TAGS: transparent extra decor
+SHUFFLE: ABCDEF, GHIJK, LMNOPQ, RSTUVW
+SUBST: AGMNOPQSTUVW = ., BCDEFHIJKLR = x
+MAP
+      ......      ......
+    ..........  ..........
+  ......cc..........cc......
+......BBccCC......KKccJJ......
+....BBBBMMCCCC..KKKKSSJJJJ....
+..ccBB..MM..CCccKK..SS..JJcc..
+..ccLL..MM..NNccRR..SS..TTcc..
+..AALLLLMMNNNNDDRRRRSSTTTTII..
+..AA..LLccNN..DD..RRccTT..II..
+..AA..QQccOO..DD..WWccUU..II..
+..AAQQQQPPOOOODDWWWWVVUUUUII..
+..ccQQ..PP..OOccWW..VV..UUcc..
+..ccFF..PP..EEccGG..VV..HHcc..
+....FFFFPPEEEE..GGGGVVHHHH....
+......FFccEE......GGccHH......
+  ......cc..........cc......
+    ..........  ..........
+      ......      ......
+ENDMAP
+
 #####################################################################
 #
 # <<2>> Inaccessible items